# Daily Blog
# Main Page

global prefix hardprefix
# The URL of the Blog:
set prefix "/school"
set hardprefix "/aaron/school"

source "/web/swartzfam/aaron/school/definitions.tcl"

# Procedure to display a page using the template
proc sa_display_page {title content {extra ""} {status 200}} {
	global hardprefix prefix
	ns_return $status text/html [ns_adp_parse -file "[ns_info pageroot]$hardprefix/main-template.adp" $title $extra $content]
}

proc sa_check_password {} {
	global password
	if {[regexp {password=([^;]+)} [ns_set get [ns_conn headers] "Cookie"] {} pass] && \
	$pass == $password} {
		return 1
	} {
		return 0
	}
}

proc sa_require_admin {} {
	if {![sa_check_password]} {
		sa_returnredirect "/login/"
		return -code return
	}
}

proc sa_edit_button {post_date} {
	global hardprefix prefix
	if {[sa_check_password]} {
		return "<p><form method=\"get\" action=\"$prefix/edit/\">[export_form_vars post_date]<input type=\"submit\" value=\"Edit This Page!\"></form></p>"
	} {return ""}
}

proc sa_email_button {post_date} {
	global hardprefix prefix 
	if {[sa_check_password]} {
		return "<p><form method=\"get\" action=\"$prefix/sendemail/\">[export_form_vars post_date]<input type=\"submit\" value=\"Send the Emails!\"></form></p>"
	} {return ""}
}
proc sa_nav {post_date} {
	append out "\["
	
	global db hardprefix prefix
	set prev_date [database_to_tcl_string_or_null $db "SELECT post_date FROM sa_entries WHERE post_date < '$post_date' ORDER BY post_date DESC LIMIT 1"]
	if {$prev_date != ""} {
		regsub -all -- {-} $prev_date {/} prev_date
		append out "<a href=\"$prefix/$prev_date/\" class=\"nav\">"
		set later "</a>"
	} {set later ""}
	
	regsub -all -- {-} $post_date {/} post_date
		
	append out "&lt;$later <a href=\"$prefix/$post_date/\" class=\"nav\">*</a> "
	
	
	set next_date [database_to_tcl_string_or_null $db "SELECT post_date FROM sa_entries WHERE post_date > '$post_date' ORDER BY post_date ASC LIMIT 1"]
	if {$next_date != ""} {
		regsub -all -- {-} $next_date {/} next_date
		append out "<a href=\"$prefix/$next_date/\" class=\"nav\">"
		set later "</a>"
	} {set later ""}
	
	append out "&gt;$later\]"
	return $out
}

proc sa_returnredirect {url} {
	global hardprefix servername prefix
	ns_returnredirect "$servername$prefix$url"
}

proc sa_display_entry {entry {full_url 0}} {
	global hardprefix prefix servername
	if {$full_url} {set starter $servername}
	append starter $prefix
	regsub -all -nocase {<a href ?= ?"//} $entry "<a href=\"$starter/" entry
	return $entry
}

proc sa_display_message {status} {
	switch $status {
		"done" {return ""}
		default {return "<p><em>This entry hasn't been officially posted yet -- we're still working on it, so don't take anything too seriously. Thanks!</em></p>"}
	}
}

proc sa_get_special {} {
	set content ""
	set rd [open /web/swartzfam/aaron/school/unschool.htmf RDONLY]
	while {![eof $rd]} {
		append content [read $rd]
	}
	return $content
}

set url [string range [ns_conn url] [string length $hardprefix] end]

global db
set db [ns_db gethandle]
catch {ns_db dml $db "INSERT INTO sa_log(url, referer, visit_time, ip) VALUES('[DoubleApos $url]','[DoubleApos [ns_set iget [ns_conn headers] "Referer"]]','now','[DoubleApos [ns_set iget [ns_conn headers] "X-Peer-Addr"]]')"}

# Smash case after we've logged it:
set out_type ""
set test_url [string tolower $url]
regexp {(/?(.*/)?)index\.([^/]*)$} $test_url {} test_url {} out_type
switch $test_url {
	"/login/" {
		if {[sa_check_password]} {set status "<p>You are currently <strong>logged in</strong>.</p>"} {set status ""}
		sa_display_page "Login" \
"$status
<p>To gain administrator access, please enter the secret password below:</p>
<form action=\"../login2/\" method=\"post\">
	<input name=\"password\" type=\"password\"><br>
	<em>Remember?</em> <input name=\"save\" type=\"checkbox\" value=\"t\">
	<input type=\"submit\" value=\"Log In\">
</form>"
		return
	}
	"/login2/" {
		set pass [ns_queryget password]
		if {$pass != $password} {
			sa_display_page "Bad Password" "<p>Sorry, that's the wrong password.</p>"
			return
		}
		if {[ns_queryexists save]} {set expire_val ";expires=Fri, 01-Jan-2010 01:00:00 GMT"} else {set expire_val ""}
		ns_set put [ns_conn outputheaders] "Set-Cookie" "password=$password$expire_val;path=$prefix"
		sa_returnredirect "/"
		return
	}
	"/edit/" {
		sa_require_admin
		set post_date [ns_queryget post_date]
		if {$post_date == ""} {
			sa_display_page "Value Required" "<p>You need to supply something to edit!</p>"
			return
		}
		if {[regexp {^[-0-9]+$} $post_date]} {
			set table "sa_entries"
			set column "post_date"
			set title_sql ""
		} {
			set table "sa_stories"
			set column "url"
			set title_sql ", title"
		}
		set selection [ns_db 0or1row $db "SELECT body, status$title_sql FROM $table
			WHERE $column = '$post_date'"]
		if {$selection != ""} {
			set_variables_after_query
			set post_url $post_date
			if {$table == "sa_entries"} {regsub -all -- {-} $post_url {/} post_url}
			set view "<p><a href=\"../$post_url/\">Take a look</a> at your work.</p>"
			if {$status == "done"} {set status " checked"} {set status ""}
		} {
			set body ""
			set view ""
			set status ""
		}
		if {$table == "sa_stories"} {
			if {![info exists title]} {set title ""}
			set title_html "<strong>Title:</strong> <input type=\"text\" name=\"title\" value=\"[ns_quotehtml $title]\" size=\"70\"><br>"
		} else {
			set title_html ""
		}
		sa_display_page "Edit" "$view
<form action=\"../edit2/\" method=\"post\">
<strong>Secret Code:</strong> $post_date<br>
[export_form_vars post_date]
$title_html
<textarea rows = \"20\" cols = \"75\" name=\"body\">$body</textarea><br>
<em>Published?</em> <input type=\"checkbox\" name=\"status\" value=\"1\"$status><br>
<em>Convert to HTML?</em> <input type=\"checkbox\" name=\"html_conv\" value=\"1\"><br>
<input type=\"submit\" value=\"Save\"> <input type=\"submit\" name=\"delete\" value=\"Delete\">
</form>"
		return
	}
	"/edit2/" {
		sa_require_admin
		set post_date [DoubleApos [ns_queryget post_date]]
		set body [DoubleApos [ns_queryget body]]
		if {[ns_queryget html_conv] == "1"} {set body [ad_text_to_html $body]}
		set delete_p [ns_queryexists delete]
		if {[ns_queryexists status]} {set status "done"} {set status "editing"}
		if {[regexp {^[0-9]} $post_date]} {
			set table "sa_entries"
			set column "post_date"
			set title1 ""
			set title2 ""
			set title3 ""
		} {
			set table "sa_stories"
			set column "url"
			set title1 ",title,add_date"
			set title2 ",'[DoubleApos [ns_queryget title]]','now'"
			set title3 ", title = '[DoubleApos [ns_queryget title]]', mod_date = 'now'"
		}
		
		set exists_p [database_to_tcl_string $db "SELECT count(*) FROM $table WHERE $column = '$post_date'"]
		if {$delete_p} {
			ns_db dml $db "DELETE FROM $table WHERE $column = '$post_date'"
		} elseif {$exists_p} {
			ns_db dml $db "UPDATE $table SET body = '$body', status = '$status'$title3 WHERE $column = '$post_date'"
		} else {
			ns_db dml $db "INSERT INTO ${table}(body,$column,status$title1) VALUES('$body','$post_date','$status'$title2)"
		}
		
		sa_returnredirect "/edit/?[export_url_vars post_date]"
		return
	}
	"/source/" {
		set fp [open "[ns_info pageroot]$hardprefix/main.tcl" r]
		while {![eof $fp]} {
			append code [read $fp]
		}
		close $fp
		ns_return 200 text/plain $code
		return
	}
	"/subscribe/" {
		sa_display_page "Subscribe" {
<h2>Subscribe by Email</h2>

<p>Would you like to receive updates to this site by email? 
We promise not to give out your email address to anyone else. (Don't worry, we hate spam too.)
Enter your email address below to subscribe:</p>

<form method="post" action="../subscribe2/">
<strong>Email Address:</strong> <input type="text" name="email" size="50"> <input type="submit" value="Subscribe">
</form>}
		return
	}
	"/subscribe2/" {
		set email [ns_queryget email]
		if {![philg_email_valid_p $email]} {
			sa_display_page "Invalid Email" {<h2>Invalid Email</h2>
<p>Sorry, that email is invalid. Examples of valid email addresses are:</p>

<ul>
	<li>Alice1234@aol.com</li>
	<li>joe_smith@hp.com</li>
	<li>pierre@inria.fr</li>
</ul>
<p>Please <a href="../subscribe/">go back</a> and try again.</p>}
			return
		}

		# Make sure they're not already subscribed:
		if {[database_to_tcl_string $db "SELECT count(email) FROM sa_subscribers 
			WHERE email = '[DoubleApos $email]'
			AND remove_date IS NULL"]} {
			sa_display_page "Already Subscribed" "<h2>Already Subscribed</h2>
<p>That email address is already subscribed! You can also 
<a href=\"../unsubscribe2/?[export_url_vars email]\">unsubscribe</a>.</p>"
			return
		}
		set code [as_random_string 5]
		
		# Stick them in the database:
		set try 0
		while {[catch {ns_db dml $db "INSERT INTO sa_subscribers(email,add_date,code,sent_p) 
			VALUES ('[DoubleApos $email]','now','$code','f')"} errMsg] && $try < 5} {
			incr try
			# Could be a duplicate secret code -- regenerate
			set code [as_random_string 5]
		}
		
		sa_display_page "Subscribed" "<h2>Subscribed</h2>
<p>You've been subscribed to receive updates by email. You've been sent an email with more information and instructions on how to unsubscribe.</p>"
		ns_conn close
		ns_sendmail $email $webmaster "Subscribed to $sitename" \
"You've been subscribed to receive updates on $sitename:

$servername$prefix/

If you didn't mean to subscribe, or would like to unsubscribe, you can 
unsubscribe at any time by visiting:

$servername$prefix/unsubscribe2/?code=$code

Enjoy!

$webmaster_name"
		return
	}
	"/unsubscribe/" {
		sa_display_page "Unsubscribe" {<h2>Unsubscribe</h2>
<p>Annoyed about the emails? Enter your email address below to unsubscribe:</p>
<form method="post" action="../unsubscribe2/">
<strong>Email Address:</strong> <input type="text" name="email" size="50"> <input type="submit" value="Unsubscribe">
</form>}
		return
	}
	"/unsubscribe2/" {
		if {[ns_queryexists code]} {
			set code [ns_queryget code]
			# Wants to unsubscribe
			ns_db dml $db "UPDATE sa_subscribers
				SET remove_date = 'now' 
				WHERE remove_date IS NULL
				AND code = '[DoubleApos $code]'"
			sa_display_page "Unsubscribed" "<h2>Unsubscribed</h2>
<p>You have been successfully unsubscribed. Sorry you didn't like it!</p>"
			return
		} elseif {[ns_queryexists email]} {
			set email [ns_queryget email]
			set code [database_to_tcl_string_or_null $db "SELECT code FROM sa_subscribers
				WHERE email = '[DoubleApos $email]'
				AND remove_date IS NULL"]
			if {$code == ""} {
				sa_display_page "Not Subscribed" "<h2>Not Subscribed</h2>
<p>You couldn't be unsubscribed because you weren't subscribed. Oh well, nothing to worry about then.</p>"
				return
			} 
			ns_sendmail $email $webmaster "Unsubscribing" "To unsubscribe visit this URL:

$servername$prefix/unsubscribe2/?code=$code

Thanks!"
			sa_display_page "Check Your Email" "<h2>Check Your Email</h2>
<p>We've sent you an email with instructions on how to unsubscribe. Just go ahead and follow them.</p>"
			return
		} else {
			sa_returnredirect "/unsubscribe/"
		}
	}

	"/sendcp/" {
		sa_require_admin
		set selection [ns_db select $db "SELECT DISTINCT responder,target FROM sa_cp"]
		while {[ns_db getrow $db $selection]} {
			set_variables_after_query
			append result "[ta_httppost $responder "url=[ns_urlencode $target]"]\n"
		}
		ns_return 200 text/plain "$responder: did it: $result"
		return
	}

	"/sendemail/" {
		sa_require_admin
		set total [database_to_tcl_string $db "SELECT count(*) FROM sa_subscribers WHERE remove_date IS NULL"]
		set unsent [database_to_tcl_string $db "SELECT count(*) FROM sa_subscribers WHERE remove_date IS NULL AND sent_p = 'f'"]
		set post_date [ns_queryget post_date]
		regsub -all -- {-} $post_date / addy
		set body [database_to_tcl_string $db "SELECT body FROM sa_entries WHERE post_date = '$post_date'"]
		if {$post_date == "2001-04-05"} {
			set body [sa_get_special]
		}
		set email_text "Here's today's update from $sitename:

[ad_html_to_text "<hr>"]
[ad_html_to_text [sa_display_entry $body 1]]
[ad_html_to_text "<hr>"]

Like this update? Visit it online at:

$servername$prefix/$addy/"
		sa_display_page "Send Emails" "<h2>Send Emails</h2> 
<p><strong>Current email state:</strong> $unsent unsent of $total</p> 
<form action=\"$prefix/sendemail2/\" method=\"post\">
<strong>Subject:</strong> <input name=\"subject\" type=\"text\"/> <br />
<textarea name=\"body\" cols=\"80\" rows=\"[expr [regsub -all {\n} $email_text {} {}] + 1]\">
$email_text
</textarea>
<input type=\"submit\" value=\"Send\"><br />
Reset: <input type=\"checkbox\" name=\"reset\" value=\"1\" checked=\"checked\">
</form>"
		return
	}
	"/sendemail2/" {
		set body [ns_queryget body]
		set subject [ns_queryget subject]
		if {[set reset [ns_queryexists reset]]} {
			set reset [ns_queryget reset]
		}
		sa_require_admin	
		sa_returnredirect "/sendemail3/"
		ns_conn close
		if {$reset} {
			# Reset the sent_p flag:
			ns_db dml $db "UPDATE sa_subscribers SET sent_p = 'f'"
		}
		set email_list [database_to_tcl_list_list $db "SELECT email, code FROM sa_subscribers WHERE remove_date IS NULL"]
		foreach person_list $email_list {
			catch {
			ns_sendmail [lindex $person_list 0] $webmaster "$subject ($sitename)" $body
			ns_db dml $db "UPDATE sa_subscribers SET sent_p = 't' WHERE email = '[DoubleApos [lindex $person_list 0]]' AND remove_date IS NULL"
			}
		}
		return
	}
	"/sendemail3/" {
		sa_require_admin
		set total [database_to_tcl_string $db "SELECT count(*) FROM sa_subscribers WHERE remove_date IS NULL"]
		set sent [database_to_tcl_string $db "SELECT count(*) FROM sa_subscribers WHERE remove_date IS NULL AND sent_p = 't'"]
		set selection [ns_db select $db "SELECT email, sent_p FROM sa_subscribers WHERE remove_date IS NULL"]
		set email_list ""
		while {[ns_db getrow $db $selection]} {
			set_variables_after_query
			append email_list "<br>$email <em>($sent_p)</em>"
		}
		sa_display_page "Email Status" "<h2>Email Status</h2>
<p><strong>Don't Forget:</strong> Send out <a href=\"../sendcp/\">the notifications</a> too!</p>

<p><strong>Status:</strong> $sent sent of $total</p>
$email_list"
		return
	}
	"/viewall/" {
		set selection [ns_db select $db "SELECT post_date FROM sa_entries ORDER BY post_date"]
		append page_content "<h2>View All Entries</h2>
		<ul>"
		while {[ns_db getrow $db $selection]} {
			set_variables_after_query
			regsub -all -- {-} $post_date {/} post_url
			append page_content "<li><a href=\"../$post_url/\">$post_date</a></li>"
		}
		append page_content "</ul>"
		sa_display_page "View All Entries" $page_content
		return
	}
	"/linkback/" {
		sa_require_admin
		set page_content "<p>The link report:</p>\n<ul>"
		set selection [ns_db select $db "SELECT referer, count(referer) AS n
			FROM sa_log WHERE referer NOT LIKE 'http://%swartzfam.com/aaron/school/%'
			GROUP BY referer
			ORDER BY count(referer) DESC"]
		while {[ns_db getrow $db $selection]} {
			set_variables_after_query
			append page_content "	<li><code>$referer</code> ($n)</li>\n"
		}
		append page_content "</ul>"
		sa_display_page "Linkback Report" $page_content
		return
	}
	"/rss092/" {
		source [ns_info pageroot]$hardprefix/rss092.tcl
		return
	}
	"/cp/" {
		source [ns_info pageroot]$hardprefix/cp.tcl
		return
	}
	"" - "/" - "/index.*" {}
	default {
		set id [string trimleft [string trimright $test_url "/"] "/"]
		if {$test_url != "/$id/"} {
			sa_returnredirect "/$id/"
			return
		}
		set selection [ns_db 0or1row $db "SELECT body, status, title, mod_date FROM sa_stories WHERE url = '[DoubleApos $id]'"]
		if {$selection != ""} {
			set_variables_after_query
			switch $out_type {
				xhtml {ns_return 200 text/html \
"<html><head><title>$title</title></head>
<body>
[sa_display_message $status][sa_display_entry $body]
</body>
</html>"}
				school {
					append page_content \
"<html><head>
	<title>$title</title>
	<style type=\"text/css\">
	<!--
	P {line-height: 2}
	-->
	</style>
</head>
<body>
<div align=\"right\">Aaron Swartz, $mod_date<br>
<code>$servername$prefix/$id/</code></div>
[sa_display_message $status][sa_display_entry $body]"
					set href_list [ns_hrefs [sa_display_entry $body 1]]
					if {[llength $href_list] > 0} {
						append page_content "<h3>URLs</h3>
<p><pre>"
						set later "</pre></p>"
		 			} {set later ""}
					foreach href_url $href_list {
						append page_content "\n$href_url"
					}
					append page_content "$later
</body>
</html>"
					ns_return 200 text/html $page_content
}
				html - default {sa_display_page $title "[sa_display_message $status][sa_display_entry $body][sa_edit_button $id]"}
			}
			return
		} elseif {![regexp {^/[0-9]} $url]} {
			sa_display_page "File Not Found" "<p>Sorry, the page you requested does not exist. You may want to email <a href=\"mailto:$webmaster\">the webmaster</a> to complain.</p>[sa_edit_button $id]" "" 404
			return
		}
	}
}

set year ""
set month ""
set day ""
set match ""
set type ""

regexp {/([0-9]+)(/([0-9]+))?(/([0-9]+))?} $test_url match year {} month {} day

if {"$match/" != $test_url} {
	sa_returnredirect "$match/"
}

if {$day == ""} {
	if {$month == ""} {
		if {$year == ""} {
			
			# Show Today's Blog:
			set selection [ns_db 0or1row $db "SELECT body, status, post_date FROM sa_entries 
				ORDER BY post_date DESC
				LIMIT 1"]
			if {$selection == ""} {
				sa_display_page "Today's Blog" "<p>Sorry, there are no entries quite yet. You'll have to wait until something is written!</p>"
			} {
				set_variables_after_query
				if {$post_date == "2001-04-05"} {
					set body [sa_get_special]
				}
				switch $out_type {
					"xhtml" {
						ns_return 200 text/html \
"<html><head><title>Schoolyard Subversion: Today's Update</title></head>
<body>
	<h1>$post_date</h1>
	[sa_display_message $status]
	[sa_display_entry $body]
</body>
</html>"
					}
					"html" - default {
						sa_display_page "Today's Blog" "[ns_adp_parse -file "[ns_info pageroot]$hardprefix/today-template.adp" $post_date "[sa_display_message $status][sa_display_entry $body]"][sa_edit_button $post_date][sa_email_button $post_date]"
					}
				}
			}

		} else {
		
			# Show the year:
			sa_display_page "Year's Blog" "For the year of $year"
		}
	} else {
	
		# Show the month:
		sa_display_page "Month's Blog" "For the month of $month in the year $year"
	}
} else {
	
	# Show the day:
	# Fix bad year representation:
	if {[string length $year] < 4} {
		set year "000$year"
	}
	if {[catch {
	set selection [ns_db 0or1row $db "SELECT body, post_date, status FROM sa_entries 
		WHERE post_date = '$year-$month-$day'"]
}] || $selection == ""} {
		sa_display_page "Not Available" "<p>Sorry, there was no entry on that date. Try <a href=\"../\">that month</a>, <a href=\"../../\">that year</a>, or <a href=\"../../../\">the latest entry</a>.</p>[sa_edit_button "$year-$month-$day"]"
	} else {
		set_variables_after_query
		if {$post_date == "2001-04-05"} {
			set body [sa_get_special]
		}
		switch $out_type {
				xhtml {ns_return 200 text/html \
"<html><head><title>$title</title></head>
<body>
[sa_display_message $status][sa_display_entry $body]
</body>
</html>"}
				school {
					append page_content \
"<html><head>
	<title>Schoolyard Subversion</title>
	<style type=\"text/css\">
	<!--
	BODY {font-family: Georgia;}
	-->
	</style>
</head>
<body>
<div align=\"right\">Aaron Swartz<br>
On the Web at <code>$servername$prefix$test_url</code></div>
[sa_display_message $status][sa_display_entry $body]"
					set href_list [ns_hrefs [sa_display_entry $body 1]]
					if {[llength $href_list] > 0} {
						append page_content "<h3>URLs</h3>
<p><pre>"
						set later "</pre></p>"
		 			} {set later ""}
					foreach href_url $href_list {
						append page_content "\n$href_url"
					}
					append page_content "$later
</body>
</html>"
					ns_return 200 text/html $page_content
}
				html - default {sa_display_page "Day Blog" "[sa_display_message $status][ns_adp_parse -file "[ns_info pageroot]$hardprefix/day-template.adp" $post_date [sa_display_entry $body]][sa_edit_button $post_date]"}
			}
	}
}